Address 5VZC2Q27X24MHE2LH5B7RKN6L2FSADKF, transactions and portfolio

5VZC2Q27X24MHE2LH5B7RKN6L2FSADKF

Definition

1	[
2	"autonomous agent",
3	{
4	"bounce_fees": {
5	"base": 10000
6	},
7	"init": "{
8	$HOUSE_CUT = 0.1; //We will take this cut on the debut of an NFT in our platform. We charge 0.1% for foreign NFTs.
9	$FREEMARKET_CUT = 0.001; //We take 0.1% on every foreign NFT trade
10	$ARTIST_CUT = 0.01; //The artist will get 1% from every resale of their NFT
11	$INVESTMENT_CUT = 0.01;//We take a 1% cut from all maecenas investments
12	$HALF_HOUR = 1800; //30m = 1800s. An auction is extended by 1800s every time there is a new bid near the deadline
13	$RESERVE_AMOUNT = 200000; //We will always keep > 200.000 in the AA
14	$MIN_BID_INCREMENT = 0.0001;
15
16	$extendDeadLine = $NFT=>($NFT.soldAt <= timestamp + $HALF_HOUR) ? ($NFT \|\| {soldAt: $NFT.soldAt + $HALF_HOUR}) : $NFT; //Extend the auction if there is a bid less than half an hour before the auction is closed
17	/*
18	** Strips $NFT of computed fields to reduce AA's storage size
19	*/
20	$stripToken = $NFT=>{
21	delete($NFT, "isBanned");
22	delete($NFT, "issuer");
23	delete($NFT, "cap");
24	delete($NFT, "mintedAt");
25	delete($NFT, "duration"); //For foreign NFTs
26	delete($NFT, "meta");
27	return $NFT;
28	};
29
30	if (NOT exists(trigger.data["method"]))
31	bounce("method field is mandatory");
32
33	$spendableFunds = balance["base"] - var["locked"] - storage_size - $RESERVE_AMOUNT;
34	$owner = var["owner"];
35	$calculateSharesToBuy = ($price, $pool, $myShare)=>ln($price/($pool*$myShare))/ln($myShare);
36	}",
37	"getters": "{
38	$_maecenasCurve = $x=>6969420 * $x^2;
39
40	//DEBUG $_maecenasCurve = $x=>20000*$x^2;
41	// TOKEN RELATED GETTERS
42
43	/*
44	** All the information about the given NFT sale
45	*/
46	$tokenInfo = $NFT=>{
47	$unit = unit[$NFT];
48	$tok = var[$NFT];
49
50	if (NOT $tok)
51	bounce("NFT not found");
52
53	$feedData = data_feed[[oracles=this_address, feed_name=$NFT, ifnone="false", ifseveral="last", type="string"]];
54
55	return $tok \|\|
56	{
57	isBanned: $feedData == "REVOKED" ? true : false,
58	cap: $unit.messages[[.app="asset"]].payload.cap,
59	mintedAt: $unit.timestamp,
60	issuer: asset[$NFT].definer_address,
61	meta: var["meta_" \|\| $NFT]
62	};
63	};
64
65
66
67	$saleInfo = $NFT=>{
68	$unit = unit[$NFT];
69	$info = var["NFT_" \|\| $NFT];
70
71	if (NOT $info)
72	bounce("That NFT is not for sale or does not exist");
73
74	return $info \|\| {
75	cap: $unit.messages[[.app="asset"]].payload.cap,
76	mintedAt: $unit.timestamp
77	};
78	};
79
80
81	/*
82	** How many copies of the NFT were sold, bounces if we did not mint the NFT
83	*/
84	$circulatingSupply = $NFT=>{
85	$info = $tokenInfo($NFT);
86
87	if ($info.isBanned)
88	bounce("That NFT was revoked");
89
90	if ($info.issuer != this_address)
91	bounce("That NFT was not minted by us, thus we don't know how many of them are out in the wild");
92
93	return $info.unitsSold OTHERWISE 1;
94	};
95
96	//ARTIST AND MAECENAS RELATED GETTERS
97	/*
98	** All the artist information
99	*/
100
101	$artistInfo = $artist=>var["artist_" \|\| $artist];
102	$profile = $artist=>var["profile_" \|\| $artist];
103	/*
104	** How many BYTES have maecenas invested in a given artist
105	*/
106	$totalArtistInvestment = $artist=>{
107	if (NOT is_valid_address($artist))
108	bounce("artist address is invalid");
109
110	$artistInf = $artistInfo($artist);
111
112	if (typeof($artistInf) == "boolean")
113	bounce("That artist does not accept maecenas");
114
115	return 11511570 * $artistInf.supply * (1 + $artistInf.supply) * (1 + 2 * $artistInf.supply);
116	};
117	/*
118	** How many BYTES does the next share of the given artist costs
119	*/
120	$artistSharePrice = $artist=>{
121	$artistInf = var["artist_" \|\| $artist];
122
123	if (NOT $artistInf)
124	bounce("That artist does not accept investments");
125
126	return $_maecenasCurve($artistInf.supply);
127	};
128	/*
129	** How many BYTES does it take to buy $shares amount of the given artist shares
130	*/
131	$artistSharesPrice = ($artist, $shares)=>{
132	if (NOT is_integer($shares))
133	bounce("shares must be an integer");
134	if ($shares <= 0)
135	bounce("shares must be a positive integer");
136	if (NOT is_valid_address($artist))
137	bounce("artist address is invalid");
138
139	$artistInf = $artistInfo($artist);
140
141	if (NOT $artistInf)
142	bounce("That artist does not accept maecenas");
143
144	$x0 = $artistInf.supply;
145	$x1 = $artistInf.supply + $shares;
146
147	$upToFirstToken = 1161570 * $x0 * (1 + $x0) * (1 + 2 * $x0);
148	$upToTargetPurchase = 1161570 * $x1 * (1 + $x1) * (1 + 2 * $x1);
149	return round($upToTargetPurchase - $upToFirstToken, 0);
150	};
151	/*
152	** How many SHARES of the given artist has the given maecenas
153	*/
154	$maecenasArtistShares = ($maecenas, $artist)=>{
155	if (NOT is_valid_address($artist))
156	bounce("artist address is invalid");
157
158	if (NOT is_valid_address($maecenas))
159	bounce("maecenas address is invalid");
160
161	return var["maecenas_" \|\| $maecenas \|\| "_" \|\| $artist] OTHERWISE 0;
162	};
163	/*
164	** How many BYTES have an investor accrued from the given artist
165	*/
166	$maecenasEarnings = ($maecenas, $artist)=>{
167	if (NOT is_valid_address($artist))
168	bounce("artist address is invalid");
169
170	if (NOT is_valid_address($maecenas))
171	bounce("maecenas address is invalid");
172
173	$artistInf = $artistInfo($artist);
174
175	return floor($artistInf.share * $maecenasArtistShares($maecenas) / $artistInf.supply, 0);
176	};
177	}",
178	"messages": {
179	"cases": [
180	{
181	"if": "{
182	NOT $owner //The owner has not been set
183	}",
184	"messages": [
185	{
186	"app": "state",
187	"state": "{
188	var["owner"] = "IUU43O7TS2TBYKAPGKUARDZHOTAE275A"; //Set the Owner to my address
189	var["locked"] = 0; //Bytes locked in bids are not withdrawable by the Owner
190	}"
191	}
192	]
193	},
194	{
195	"if": "{
196	trigger.address == $owner
197	AND (trigger.data["method"] == "mint"
198	OR trigger.data["method"] == "payout"
199	OR trigger.data["method"] == "approve"
200	OR trigger.data["method"] == "revoke"
201	OR trigger.data["method"] == "transferOwnership"
202	OR trigger.data["method"] == "verifyProfile")
203	}",
204	"messages": {
205	"cases": [
206	{
207	"if": "{
208	trigger.data["method"] == "mint"
209	}",
210	"init": "{
211	if (NOT exists(trigger.data["amount"]))
212	bounce("amount field is mandatory");
213	if (NOT is_valid_amount(trigger.data["amount"]))
214	bounce("The amount of NFT copies to mint is not valid");
215	if (NOT exists(trigger.data["ipfs"]))
216	bounce("ipfs field is mandatory");
217	if (NOT exists(trigger.data["seller"]))
218	bounce("seller field is mandatory");
219	if (NOT is_valid_address(trigger.data["seller"]))
220	bounce("The seller address is not valid");
221	if (NOT exists(trigger.data["endTime"]))
222	bounce("endTime field is mandatory");
223	if (NOT is_integer(trigger.data["endTime"]))
224	bounce("endTime field is not a timestamp");
225	if (trigger.data["endTime"] <= timestamp)
226	bounce("The endTime cannot be set in the past");
227	if (trigger.data["endTime"] - timestamp > 2628000)
228	bounce("You cannot set the end time in more than 30 days in the future");
229	}",
230	"messages": {
231	"cases": [
232	{
233	"if": "{
234	trigger.data["amount"] == 1
235	}",
236	"messages": [
237	{
238	"app": "asset",
239	"payload": {
240	"cap": 1,
241	"is_private": false,
242	"is_transferrable": true,
243	"auto_destroy": false,
244	"fixed_denominations": false,
245	"issued_by_definer_only": true,
246	"cosigned_by_definer": false,
247	"spender_attested": false
248	}
249	},
250	{
251	"app": "state",
252	"state": "{
253	var["NFT_" \|\| response_unit] = {
254	bid: 20000, //Max current bid (a NFT can have this field because it was resold. Check for price field instead)
255	by: trigger.data["seller"],
256	at: timestamp, //Max bid time
257	ipfs: trigger.data["ipfs"], //Hash of the content
258	author: trigger.data["seller"], //The original seller
259	soldAt: trigger.data["endTime"], //End of the auction
260	soldBy: trigger.data["seller"] //Who is currently selling the NFT
261	};
262	}"
263	}
264	]
265	},
266	{
267	"init": "{
268	if (NOT exists(trigger.data["price"]))
269	bounce("price field is mandatory if you intend to sell more than one NFT copy");
270	if (trigger.data["price"] < 20000)
271	bounce("The minium price is 20000 bytes");
272	if (NOT is_valid_amount(trigger.data["price"]))
273	bounce("price is not valid");
274	}",
275	"messages": [
276	{
277	"app": "asset",
278	"payload": {
279	"cap": "{trigger.data["amount"]}",
280	"is_private": false,
281	"is_transferrable": true,
282	"auto_destroy": false,
283	"fixed_denominations": false,
284	"issued_by_definer_only": true,
285	"cosigned_by_definer": false,
286	"spender_attested": false
287	}
288	},
289	{
290	"app": "state",
291	"state": "{
292	var["NFT_" \|\| response_unit] = {
293	price: trigger.data["price"], //Sale price (this field is only present if the first sale was a fixed price one)
294	at: timestamp, //Max bid time
295	ipfs: trigger.data["ipfs"], //Hash of the content
296	unitsSold: 0,
297	author: trigger.data["seller"], //The original seller
298	soldAt: trigger.data["endTime"], //End of the auction
299	soldBy: trigger.data["seller"] //Who is currently selling the NFT
300	};
301	}"
302	}
303	]
304	}
305	]
306	}
307	},
308	{
309	"if": "{
310	trigger.data["method"] == "payout"
311	}",
312	"init": "{
313	if ($spendableFunds <= 20000)
314	bounce("There are not enought funds to withdraw");
315	}",
316	"messages": [
317	{
318	"app": "payment",
319	"payload": {
320	"asset": "base",
321	"outputs": [
322	{
323	"address": "{trigger.address}"
324	}
325	]
326	}
327	}
328	]
329	},
330	{
331	"if": "{
332	trigger.data["method"] == "approve"
333	}",
334	"init": "{
335	if (NOT exists(trigger.data["NFT"]))
336	bounce("NFT field is mandatory");
337
338	$NFT = var["pending_" \|\| trigger.data["NFT"]];
339
340	if (NOT $NFT)
341	bounce("That NFT is not known by this AA");
342	}",
343	"messages": [
344	{
345	"app": "state",
346	"state": "{
347	$isFreeNFT = var["free_" \|\| trigger.data["NFT"]];
348	if ($isFreeNFT)
349	var["free_" \|\| trigger.data["NFT"]] = false; //Delete previous data so it is no longer tradable in the free market
350
351	var["SOLD_" \|\| trigger.data["NFT"]] = {
352	author: "foreign",
353	ipfs: $NFT.ipfs
354	};
355
356	var["pending_" \|\| trigger.data["NFT"]] = false; //Delete from the pendingApproval list
357	}"
358	}
359	]
360	},
361	{
362	"if": "{
363	trigger.data["method"] == "verifyProfile"
364	}",
365	"init": "{
366	if (NOT exists(trigger.data["artist"]))
367	bounce("artist field is mandatory");
368	}",
369	"messages": [
370	{
371	"app": "state",
372	"state": "{
373	var["profile_" \|\| trigger.data["artist"]] \|\|= {verified: true};
374	}"
375	}
376	]
377	},
378	{
379	"if": "{
380	trigger.data["method"] == "revoke"
381	}",
382	"init": "{
383	if (NOT exists(trigger.data["NFT"]))
384	bounce("NFT field is mandatory");
385	}",
386	"messages": [
387	{
388	"app": "data_feed",
389	"payload": {
390	"{trigger.data["NFT"]}": "REVOKED"
391	}
392	}
393	]
394	},
395	{
396	"if": "{
397	trigger.data["method"] == "transferOwnership"
398	}",
399	"init": "{
400	if (NOT exists(trigger.data["newOwner"]))
401	bounce("newOwner field is mandatory");
402	if (NOT is_valid_address(trigger.data["newOwner"]))
403	bounce("newOwner field is not a valid address");
404	}",
405	"messages": [
406	{
407	"app": "payment",
408	"if": "{
409	$spendableFunds > 20000
410	}",
411	"payload": {
412	"asset": "base",
413	"outputs": [
414	{
415	"address": "{trigger.address}",
416	"amount": "{$spendableFunds}"
417	}
418	]
419	}
420	},
421	{
422	"app": "state",
423	"state": "{
424	var["owner"] = trigger.data["newOwner"];//Ownership is transferred
425	}"
426	}
427	]
428	}
429	]
430	}
431	},
432	{
433	"if": "{
434	trigger.data["method"] == "BUY"
435	OR trigger.data["method"] == "DIVEST"
436	OR trigger.data["method"] == "CLAIM"
437	}",
438	"init": "{
439	$NFT = exists(trigger.data["NFT"])
440	? $saleInfo(trigger.data["NFT"])
441	: false;
442
443
444	$artist = trigger.data["method"] == "DIVEST"
445	? $artistInfo(trigger.data["artist"])
446	: $artistInfo($NFT.author);
447
448
449	if (trigger.data["method"] == "BUY"){ //Validate buy params
450	if (NOT exists(trigger.data["NFT"]))
451	bounce("NFT field is mandatory");
452
453	$isAuction = $NFT.bid ? true : false; //It can only NOT be an auction if it is first sold and thus $NFT.bid does not exist
454
455	if ($isAuction)
456	$hasBidders = ($NFT.soldBy != $NFT.by) ? true : false; //Booleans cannot be compared
457
458	if ($isAuction AND NOT $NFT.by)
459	bounce("There are no copies of that NFT listed for sale at the moment");
460
461	if (timestamp > $NFT.soldAt){
462	if ($isAuction){
463	if ($hasBidders) //You can still buy it if there were no bidders
464	bounce("The auction is over");
465	}
466	else{
467	bounce("The sale is already over");
468	}
469	}
470	}
471
472	else if (trigger.data["method"] == "DIVEST"){ //Validate divest params
473	if (NOT exists(trigger.data["artist"]))
474	bounce("artist field is mandatory");
475	if (NOT is_valid_address(trigger.data["artist"]))
476	bounce("artist's address is invalid");
477
478	if (NOT $artist)
479	bounce("That artist never accepted maecenas");
480
481	if (NOT exists(trigger.data["amount"]))
482	bounce("amount field is mandatory");
483	if (NOT is_integer(trigger.data["amount"]) OR trigger.data["amount"] <= 0)
484	bounce("amount must be an integer > 0");
485
486	$investedAmount = var["maecenas_" \|\| trigger.address \|\| "_" \|\| trigger.data["artist"]];
487
488	if (NOT $investedAmount)
489	bounce("You have no shares of that artist");
490
491	if (trigger.data["amount"] > $investedAmount)
492	bounce("You only have " \|\| $investedAmount \|\| " shares of that artist");
493
494	$yourShare = floor($artist.share * trigger.data["amount"] / $artist.supply, 0);
495
496	if ($yourShare < 20000)
497	bounce("It is not worth divesting your share");
498	}
499
500	else if (trigger.data["method"] == "CLAIM"){ //Validate claim params
501	if (NOT exists(trigger.data["NFT"]))
502	bounce("NFT field is mandatory");
503
504	$isAuction = $NFT.bid ? true : false;
505
506	if (NOT $isAuction)
507	bounce("You cannot claim a non-auction sale");
508
509	$hasBidders = ($NFT.soldBy != $NFT.by) ? true : false;
510
511	if (timestamp <= $NFT.soldAt)
512	bounce("The auction is not over yet");
513
514	if ($NFT.bid == 0)
515	bounce("That auction was already claimed");
516	}
517
518	if ($artist AND (($isAuction AND $hasBidders) OR (NOT $isAuction))){
519	$allowsMaecenas = ($artist.sharePercent >= 0.01) ? true : false;
520	$hasMaecenas = $allowsMaecenas
521	? $artist.supply > 0
522	? true
523	: false
524	: false;
525
526
527	if ($allowsMaecenas){
528	if (trigger.data["method"] == "BUY")
529	$maecenasShare = $artist.sharePercent * trigger.output[[asset="base"]].amount;
530	else if (trigger.data["method"] == "CLAIM" AND $hasBidders)
531	$maecenasShare = $artist.sharePercent * $NFT.bid;
532	else
533	$maecenasShare = 0;
534
535	$sharesInThePool = (trigger.data["method"] != "DIVEST")
536	? $artist.supply
537	: ($artist.supply - trigger.data["amount"]); //If divesting we need to substract divested shares
538
539	if (trigger.data["method"] == "DIVEST")
540	$p = $artist.share - floor((trigger.data["amount"] / $artist.supply) * $artist.share, 0); //Current share minus what was just divested
541	else
542	$p = $artist.share + $maecenasShare; //Pool value after the sale
543
544	$k = 1 / ($sharesInThePool + 1); //The fraction of the pool 1 share represents
545	$price = $_maecenasCurve($sharesInThePool + 1); //Price of buying one share
546
547
548	if (trigger.data["method"] == "BUY"){
549	if ($NFT.soldBy == $NFT.author){ //We do not need to check for auction as we do not invest in those until the claim phase
550	$totalSpendable = floor(
551	$spendableFunds
552	+ $price * $INVESTMENT_CUT //What I save from investment cut as it is paid to myself
553	+ floor(trigger.output[[asset="base"]].amount * $HOUSE_CUT, 0) //What I got as cut from the triggering tx
554	, 0);
555	}
556	else{
557	$totalSpendable = floor(
558	$spendableFunds
559	+ $price * $INVESTMENT_CUT //What I save from investment cut as it is paid to myself
560	- trigger.output[[asset="base"]].amount //Cannot spend the trigering tx as it will be locked
561	, 0);
562	}
563	}
564	else if (trigger.data["method"] == "CLAIM"){
565	$totalSpendable = floor(
566	$spendableFunds //Initial amount
567	+ $price * $INVESTMENT_CUT //What I save from investment cut
568	+ $NFT.bid * (1 - $HOUSE_CUT) //What I get from house cut
569	, 0);
570	}
571	else{
572	$totalSpendable = floor($spendableFunds + $price * $INVESTMENT_CUT, 0);
573	}
574
575	$sharesToBuy = $sharesInThePool == 0 ? 0 : ceil($calculateSharesToBuy($price, $p, $k), 0);//Can be 0 and I would still afford 1 share if profitable
576
577	if ($k == 1){
578	$sharesICanAfford = $price < $totalSpendable ? 1 : 0;
579	}
580	else {
581	if ($totalSpendable > $price AND $sharesToBuy >= 1){
582	$sharesICanAfford = floor($totalSpendable / ($price * $sharesToBuy * (1 - $INVESTMENT_CUT)), 0); //Do not buy more shares than what I can afford
583	}
584	else{
585	$sharesICanAfford = 0;
586	}
587	}
588	}
589
590	if ($allowsMaecenas AND $sharesICanAfford > 0){
591	$buyShares = true;
592	}
593	else{
594	$buyShares = false;
595	}
596
597	$shareIWillfinallyBuy = min($sharesToBuy, $sharesICanAfford); //Maybe I can afford more shares than what is profitable to buy
598	$myProfit = floor($buyShares ? $p - $p * $k^$shareIWillfinallyBuy : 0, 0); //0 if no shares are bought
599	$poolFinalValue = $p - $myProfit; //Not actual profit but what I got out of the pool
600	}
601	else {
602	$allowsMaecenas = false;
603	$buyShares = false;
604	$hasMaecenas = false;
605	$maecenasShare = 0;
606	$myProfit = 0;
607	$poolFinalValue = 0;
608	}
609	}",
610	"messages": {
611	"cases": [
612	{
613	"if": "{
614	trigger.data["method"] == "BUY"
615	}",
616	"messages": {
617	"cases": [
618	{
619	"if": "{
620	$isAuction
621	}",
622	"init": "{
623	if (trigger.output[[asset="base"]].amount < 20000)
624	bounce("The minimum bid is 20000 bytes");
625	if (trigger.output[[asset="base"]].amount <= $NFT.bid)
626	bounce("Your bid is lower or equal to the last bid. You must increase it");
627	if (trigger.output[[asset="base"]].amount <= $NFT.bid * (1 + $MIN_BID_INCREMENT))
628	bounce("Your bis must be at least " \|\| $NFT.bid * (1 + $MIN_BID_INCREMENT) \|\| " (0.01% higher than the current)");
629
630	if ($NFT.soldBy == trigger.address)
631	bounce("You cannot bid on your own auction");
632	}",
633	"messages": [
634	{
635	"app": "payment",
636	"if": "{
637	$NFT.by != $NFT.soldBy //If we don't check for this the artists could steal bytes from the AA
638	}",
639	"payload": {
640	"asset": "base",
641	"outputs": [
642	{
643	"address": "{$NFT.by}",
644	"amount": "{$NFT.bid - 10000}"
645	}
646	]
647	}
648	},
649	{
650	"app": "state",
651	"state": "{
652	var["locked"] += trigger.output[[asset="base"]].amount - ($hasBidders ? $NFT.bid : 0); //Increase non-withdrawable funds by the difference between previous and last bid
653	$NFT.bid = trigger.output[[asset="base"]].amount;
654	$NFT.by = trigger.address;
655	var["NFT_" \|\| trigger.data["NFT"]] \|\|= $stripToken($extendDeadLine($NFT));
656	}"
657	}
658	]
659	},
660	{
661	"init": "{
662	if ($NFT.unitsSold == $NFT.cap)
663	bounce("All NFT copies have been already sold");
664
665	if (trigger.output[[asset="base"]].amount < $NFT.price)
666	bounce("Your payment is lower than the NFT price. You have to send " \|\| $NFT.price \|\| " bytes");
667	}",
668	"messages": [
669	{
670	"app": "payment",
671	"if": "{
672	floor($NFT.price * (1 - $HOUSE_CUT - ($allowsMaecenas ? (($hasMaecenas OR $buyShares) ? $artist.sharePercent : 0) : 0)) - 10000, 0) > 0
673	}",
674	"payload": {
675	"asset": "base",
676	"outputs": [
677	{
678	"address": "{$NFT.soldBy}",
679	"amount": "{floor($NFT.price * (1 - $HOUSE_CUT - ($allowsMaecenas ? (($hasMaecenas OR $buyShares) ? $artist.sharePercent : 0) : 0)) - 10000, 0)}"
680	}
681	]
682	}
683	},
684	{
685	"app": "payment",
686	"payload": {
687	"asset": "{trigger.data['NFT']}",
688	"outputs": [
689	{
690	"address": "{trigger.address}",
691	"amount": 1
692	}
693	]
694	}
695	},
696	{
697	"app": "state",
698	"state": "{
699	var["NFT_" \|\| trigger.data["NFT"]] \|\|= {unitsSold: $NFT.unitsSold + 1};
700	if ($hasMaecenas){
701	var["locked"] += $maecenasShare - $myProfit;
702	var["artist_" \|\| $NFT.author] \|\|= {share: $poolFinalValue};
703	}
704	if ($NFT.unitsSold + 1 == $NFT.cap){
705	var["NFT_" \|\| trigger.data["NFT"]] = false; //Delist it from sale
706	var["SOLD_" \|\| trigger.data["NFT"]] = $stripToken($NFT); //Add it to meta
707	}
708	}"
709	}
710	]
711	}
712	]
713	}
714	},
715	{
716	"if": "{
717	trigger.data["method"] == "CLAIM"
718	}",
719	"messages": {
720	"cases": [
721	{
722	"if": "{//NFT was first sold
723	$NFT.soldBy == $NFT.author
724	}",
725	"init": "{
726	if ($hasMaecenas OR $buyShares){
727	$paymentFromShares = $shareIWillfinallyBuy * round($price * (1 - $INVESTMENT_CUT), 0);
728	$sellerPayout = floor($NFT.bid * (1 - $HOUSE_CUT - $artist.sharePercent) - 10000 + $paymentFromShares, 0);
729	}
730	else {
731	$sellerPayout = floor($NFT.bid * (1 - $HOUSE_CUT) - 10000, 0);
732	}
733	}",
734	"messages": [
735	{
736	"app": "payment",
737	"if": "{
738	$sellerPayout > 0 //enough to be worth paying
739	AND $NFT.soldBy != $NFT.by //there is at least a bid
740	}",
741	"payload": {
742	"asset": "base",
743	"outputs": [
744	{
745	"address": "{$NFT.soldBy}",
746	"amount": "{$sellerPayout}"
747	}
748	]
749	}
750	},
751	{
752	"app": "payment",
753	"payload": {
754	"asset": "{trigger.data['NFT']}",
755	"outputs": [
756	{
757	"address": "{$NFT.by}",
758	"amount": 1
759	}
760	]
761	}
762	},
763	{
764	"app": "state",
765	"state": "{
766	$decrement = $hasMaecenas //My share does not play a role here
767	? $NFT.bid - $maecenasShare //If it had maecenas the maecenas share remains locked
768	: $NFT.bid; //If it does not have maecenas all bytes are unlocked
769
770	if ($NFT.bid > 20000) //If it had no bids you don't need to reduce locked amount
771	var["locked"] -= $decrement; //These bytes are no longer locked as the artist is getting them in this same unit
772
773	var["SOLD_" \|\| trigger.data["NFT"]] = $stripToken($NFT); //Save for the next auction
774	var["NFT_" \|\| trigger.data["NFT"]] = false; //No longer listed for sale
775
776	if ($hasMaecenas AND $NFT.bid > 20000)
777	var["artist_" \|\| $NFT.author] \|\|= {share: $artist.share + $maecenasShare}; //Increase the artist pool value
778	}"
779	}
780	]
781	},
782	{
783	"messages": [
784	{
785	"app": "payment",
786	"if": "{
787	$NFT.soldBy != $NFT.by //If we don't do this check the seller could steal bytes from the AA if there were no bids
788	}",
789	"payload": {
790	"asset": "base",
791	"outputs": {
792	"cases": [
793	{
794	"if": "{
795	floor($NFT.bid * $ARTIST_CUT, 0) - 10000 > 0 //It is worth paying the original artist
796	}",
797	"outputs": [
798	{
799	"address": "{$NFT.soldBy}",
800	"amount": "{floor($NFT.bid * (1 - $ARTIST_CUT) - 10000, 0)}"
801	},
802	{
803	"address": "{$NFT.author}",
804	"amount": "{floor($NFT.bid * $ARTIST_CUT, 0) - 10000}"
805	}
806	]
807	},
808	{
809	"outputs": [
810	{
811	"address": "{$NFT.soldBy}",
812	"amount": "{floor($NFT.bid * (1 - $ARTIST_CUT) - 10000, 0)}"
813	}
814	]
815	}
816	]
817	}
818	}
819	},
820	{
821	"app": "payment",
822	"payload": {
823	"asset": "{trigger.data['NFT']}",
824	"outputs": [
825	{
826	"address": "{$NFT.by}",
827	"amount": 1
828	}
829	]
830	}
831	},
832	{
833	"app": "state",
834	"state": "{
835	var["locked"] -= $NFT.bid;
836	var["SOLD_" \|\| trigger.data["NFT"]] = $stripToken($NFT); //Save for the next auction
837	var["NFT_" \|\| trigger.data["NFT"]] = false;
838	}"
839	}
840	]
841	}
842	]
843	}
844	},
845	{
846	"if": "{
847	trigger.data["method"] == "DIVEST"
848	}",
849	"messages": [
850	{
851	"app": "payment",
852	"payload": {
853	"asset": "base",
854	"outputs": [
855	{
856	"address": "{trigger.address}",
857	"amount": "{$yourShare - 10000}"
858	}
859	]
860	}
861	},
862	{
863	"app": "state",
864	"state": "{
865	var["artist_" \|\| trigger.data["artist"]] \|\|= {
866	share: $artist.share - $yourShare, //Decrease the share by the amount just divested
867	supply: $artist.supply - trigger.data["amount"] //Decrease the supply by the shares used to divest
868	};
869
870	var["maecenas_" \|\| trigger.address \|\| "_" \|\| trigger.data["artist"]] -= trigger.data["amount"];
871	var["locked"] -= ($yourShare + $myProfit);
872	}"
873	}
874	]
875	}
876	]
877	}
878	},
879	{
880	"if": "{//[PUBLIC] Resell a NFT
881	trigger.data["method"] == "SELL"
882	}",
883	"init": "{
884	//Parameter validation
885	if (NOT exists(trigger.data["endTime"]))
886	bounce("endTime field is mandatory");
887	if (trigger.data["endTime"] < timestamp)
888	bounce("You cannot set the end time in the past");
889	if (trigger.data["endTime"] > timestamp + 2628000)
890	bounce("You cannot set the end time in more than 30 days");
891
892	if (NOT exists(trigger.data["initialPrice"]))
893	bounce("initialPrice field is mandatory");
894	if (NOT is_valid_amount(trigger.data["initialPrice"]))
895	bounce("initialPrice must be a valid amount");
896	if (trigger.data["initialPrice"] < 20000)
897	bounce("The minimum initialPrice is 20000 bytes");
898
899	//NFT validation
900	if (trigger.output[[asset!="base"]].asset == "ambigous")
901	bounce("You cannot send more than one NFT type at a time");
902
903	$feedData = data_feed[[oracles=this_address, feed_name=trigger.output[[asset!="base"]].asset, ifnone=false, ifseveral="last", type="string"]];
904
905	$NFT = var["SOLD_" \|\| trigger.output[[asset!="base"]].asset] \|\| {isBanned: $feedData == "REVOKED" ? true : false}; //[We need $NFT.isBanned]This already checks for $NFT existence
906
907	if (NOT $NFT)
908	bounce("NFT not found");
909
910	$sale = var["NFT_" \|\| trigger.output[[asset!="base"]].asset];
911
912	if (trigger.output[[asset!="base"]].amount != 1)
913	bounce("You cannot auction more than 1 copy of an NFT at a time");
914
915	if ($NFT.isBanned)
916	bounce("We revoked the trading of that token probably due to copyright reasons");
917
918	if ($sale)
919	bounce("A copy of that NFT is already being auctioned. The auction is expected to end at " \|\| timestamp_to_string($sale.soldAt) \|\| " UTC but may be delayed depending on the number of bids");
920	}",
921	"messages": [
922	{
923	"app": "state",
924	"state": "{
925	$NFT.bid = trigger.data["initialPrice"];
926	$NFT.by = trigger.address;
927	$NFT.soldBy = trigger.address;
928	$NFT.at = timestamp;
929	$NFT.soldAt = trigger.data["endTime"];
930	var["NFT_" \|\| trigger.output[[asset!="base"]].asset] = $stripToken($NFT);
931	}"
932	}
933	]
934	},
935	{
936	"if": "{
937	trigger.data["method"] == "PRELIST"
938	}",
939	"init": "{
940	if (NOT exists(trigger.data["NFT"]))
941	bounce("NFT field is mandatory");
942	if (NOT asset[trigger.data["NFT"]].exists)
943	bounce("That NFT does not exist within the Obyte network");
944
945	if (NOT exists(trigger.data["ipfs"]))
946	bounce("ipfs field is mandatory");
947
948	if (NOT is_valid_address(trigger.data["seller"]))
949	bounce("The seller address is not valid");
950
951	if (NOT exists(trigger.data["duration"]))
952	bounce("duration field is mandatory. Enter the auction duration in seconds");
953	if (NOT is_integer(trigger.data["duration"]))
954	bounce("duration field is not a valid amount of seconds");
955	if (trigger.data["duration"] < 0)
956	bounce("You cannot set a negative duration");
957	if (trigger.data["duration"] > 2628000)
958	bounce("The auction cannot last more than 30 days");
959	}",
960	"messages": [
961	{
962	"app": "state",
963	"state": "{
964	var["pending_" \|\| trigger.data["NFT"]] = {
965	ipfs: trigger.data["ipfs"] //Hash of the content
966	};
967	}"
968	}
969	]
970	},
971	{
972	"if": "{
973	trigger.data["method"] == "ENABLE_INVESTING"
974	}",
975	"init": "{
976	if (var["artist_" \|\| trigger.address])
977	bounce("You are already accepting maecenas");
978
979	if (NOT exists(trigger.data["share"]))
980	bounce("share field is mandatory");
981
982	if (NOT is_integer(trigger.data["share"]) OR trigger.data["share"] < 1 OR trigger.data["share"] > 50)
983	bounce("share must be an integer between 1 - 50");
984	}",
985	"messages": [
986	{
987	"app": "state",
988	"state": "{
989	var["artist_" \|\| trigger.address] = {
990	supply: 0,
991	share: 0,
992	sharePercent: trigger.data["share"] / 100
993	};
994	}"
995	}
996	]
997	},
998	{
999	"if": "{
1000	trigger.data["method"] == "DISABLE_INVESTING"
1001	}",
1002	"init": "{
1003	$info = $artistInfo(trigger.address);
1004
1005	if (NOT $info)
1006	bounce("You are already not accepting maecenas");
1007
1008	if ($info.supply > 0)
1009	bounce("You cannot stop accepting maecenas right now as you already have some");
1010	}",
1011	"messages": [
1012	{
1013	"app": "state",
1014	"state": "{
1015	var["artist_" \|\| trigger.address] = false;
1016	}"
1017	}
1018	]
1019	},
1020	{
1021	"if": "{
1022	trigger.data["method"] == "INVEST"
1023	}",
1024	"init": "{
1025	if (NOT exists(trigger.data["artist"]))
1026	bounce("artist field is mandatory");
1027	if (NOT is_valid_address(trigger.data["artist"]))
1028	bounce("artist field is not a valid address");
1029	if (NOT var["artist_" \|\| trigger.data["artist"]])
1030	bounce("That artist is not accepting maecenas");
1031	if (NOT exists(trigger.data["amount"]))
1032	bounce("amount field is mandatory");
1033	if (NOT is_integer(trigger.data["amount"]) OR trigger.data["amount"] <= 0)
1034	bounce("amount must be a positive integer");
1035
1036	$artist = $artistInfo(trigger.data["artist"]);
1037
1038	$x0 = $artist.supply;
1039	$x1 = $artist.supply + trigger.data["amount"];
1040
1041
1042	$upToFirstToken = 1161570 * $x0 * (1 + $x0) * (1 + 2 * $x0);
1043	$upToTargetPurchase = 1161570 * $x1 * (1 + $x1) * (1 + 2 * $x1);
1044
1045	/* DEBUG
1046	$upToFirstToken = 10000/3 * $x0 * (1 + $x0) * (1 + 2 * $x0);
1047	$upToTargetPurchase = 10000/3 * $x1 * (1 + $x1) * (1 + 2 * $x1);
1048	*/
1049	$totalCost = round($upToTargetPurchase - $upToFirstToken, 0);
1050
1051	if (trigger.output[[asset="base"]].amount < $totalCost)
1052	bounce("Your payment is not enough for that purchase. You need to send " \|\| $totalCost \|\| " bytes" \|\| (trigger.data["amount"] > 1 ? " or reduce the amount of maecenas tokens you are buying" : ""));
1053	}",
1054	"messages": [
1055	{
1056	"app": "payment",
1057	"payload": {
1058	"asset": "base",
1059	"outputs": [
1060	{
1061	"address": "{trigger.data["artist"]}",
1062	"amount": "{floor($totalCost * (1 - $INVESTMENT_CUT) - 10000, 0)}"
1063	}
1064	]
1065	}
1066	},
1067	{
1068	"app": "state",
1069	"state": "{
1070	var["artist_" \|\| trigger.data["artist"]] \|\|= {supply: $artist.supply + trigger.data["amount"]};
1071
1072	if (var["maecenas_" \|\| trigger.address \|\| "_" \|\| trigger.data["artist"]])
1073	var["maecenas_" \|\| trigger.address \|\| "_" \|\| trigger.data["artist"]] += trigger.data["amount"];
1074	else
1075	var["maecenas_" \|\| trigger.address \|\| "_" \|\| trigger.data["artist"]] = trigger.data["amount"];
1076	}"
1077	}
1078	]
1079	},
1080	{
1081	"if": "{
1082	trigger.data["method"] == "PROFILE"
1083	}",
1084	"init": "{
1085	$prof = $profile(trigger.address);
1086
1087	if ($prof.verified)
1088	bounce("You have to contact support to modify a verified profile. We do this to prevent already verified accounts from impersonating another artist");
1089
1090	$profileObj = $prof \|\| trigger.data \|\| {verified: false};
1091	delete($profileObj, "method");
1092	}",
1093	"messages": [
1094	{
1095	"app": "state",
1096	"state": "{
1097	var["profile_" \|\| trigger.address] = $profileObj;
1098	}"
1099	}
1100	]
1101	},
1102	{
1103	"if": "{
1104	trigger.data["method"] == "SET_META"
1105	}",
1106	"init": "{
1107	if (NOT exists(trigger.data["NFT"]))
1108	bounce("NFT field is mandatory");
1109
1110	$NFT = var["SOLD_" \|\| trigger.data["NFT"]];
1111
1112	if (NOT $NFT)
1113	bounce("NFT not found");
1114
1115	if ($NFT.author != trigger.address)
1116	bounce("You can only set the metadata of NFTs minted by yourself");
1117	}",
1118	"messages": [
1119	{
1120	"app": "state",
1121	"state": "{
1122	var["meta_" \|\| trigger.data["NFT"]] = trigger.data;
1123	}"
1124	}
1125	]
1126	},
1127	{
1128	"if": "{
1129	trigger.data["method"] == "CHANGE_PRICE"
1130	}",
1131	"init": "{
1132	if (NOT trigger.data["NFT"])
1133	bounce("NFT field is mandatory");
1134
1135	$NFT = var["NFT_" \|\| trigger.data["NFT"]];
1136
1137	if (NOT $NFT)
1138	bounce("NFT not found");
1139
1140	if (NOT exists(trigger.data["price"]))
1141	bounce("price field is mandatory");
1142	if (NOT is_integer(trigger.data["price"]))
1143	bounce("price must be an integer");
1144	if (NOT is_valid_amount(trigger.data["price"]))
1145	bounce("price is invalid");
1146
1147	if ($NFT.bid)
1148	bounce("You cannot change an auction price!");
1149	}",
1150	"messages": [
1151	{
1152	"app": "state",
1153	"state": "{
1154	var["NFT_" \|\| trigger.data["NFT"]] \|\|= {price: trigger.data["price"]};
1155	}"
1156	}
1157	]
1158	},
1159	{
1160	"if": "{
1161	trigger.data["method"] == "FREELIST"
1162	}",
1163	"init": "{
1164	if (trigger.output[[asset!="base"]].asset == "ambigous")
1165	bounce("You cannot send more than 1 NFT type per transaction");
1166	if (trigger.output[[asset!="base"]].amount != 1)
1167	bounce("You cannot sell more than 1 NFT unit at a time");
1168
1169	$isApproved = var["NFT_" \|\| trigger.output[[asset!="base"]].asset] OTHERWISE var["SOLD_" \|\| trigger.output[[asset!="base"]].asset];
1170
1171	if ($isApproved)
1172	bounce("That NFT is already verified, thus it cannot be traded in the free market");
1173
1174	$feedData = data_feed[[oracles=this_address, feed_name=$isApproved, ifnone="false", ifseveral="last", type="string"]];
1175	$isBanned = $feedData == "REVOKED" ? true : false;
1176
1177	if ($isBanned)
1178	bounce("We have revoked the trading of that token. Probably due to copyrights");
1179
1180	$NFT = var["FREE_" \|\| trigger.output[[asset!="base"]].asset];
1181
1182	if ($NFT.soldAt < timestamp)
1183	bounce("A copy of that NFT is already being auctioned. It is expected to end at " \|\| timestamp_to_string($NFT.soldAt) \|\| " UTC");
1184
1185
1186	if (NOT $NFT){ //We do not know about the NFT
1187	if(NOT exists(trigger.data["ipfs"]))
1188	bounce("ipfs field is required as we do not know which file that NFT represents");
1189	}
1190
1191	if (NOT exists(trigger.data["endTime"]))
1192	bounce("endTime field is mandatory");
1193	if (NOT is_integer(trigger.data["endTime"]))
1194	bounce("endTime must be integer");
1195	if (trigger.data["endTime"] < timestamp)
1196	bounce("endTime cannot be set in the past");
1197	if (trigger.data["endTime"] > timestamp + 2628000)
1198	bounce("endTime cannot be set in more than a month in the future");
1199
1200	if (exists(trigger.data["price"])){ //Is normal sale
1201	if (NOT is_valid_amount(trigger.data["price"]))
1202	bounce("price is invalid");
1203	else
1204	$toCreate = {price: trigger.data["price"]};
1205	}
1206	else{ //Is auction
1207	$toCreate = {bid: 20000, by: trigger.address, at: timestamp};
1208	}
1209	}",
1210	"messages": [
1211	{
1212	"app": "state",
1213	"state": "{
1214	var["FREE_" \|\| trigger.output[[asset!="base"]].asset] = $toCreate \|\| {ipfs: (NOT $NFT) ? trigger.data["ipfs"] : $NFT.ipfs, author: 'foreign', soldBy: trigger.address, soldAt: trigger.data["endTime"]};
1215	}"
1216	}
1217	]
1218	},
1219	{
1220	"if": "{
1221	trigger.data["method"] == "FREEBUY"
1222	}",
1223	"init": "{
1224	if (NOT trigger.data["NFT"])
1225	bounce("NFT field is mandatory");
1226	if (NOT exists(trigger.data["NFT"]))
1227	bounce("NFT field is mandatory");
1228
1229	$NFT = var["FREE_" \|\| trigger.data["NFT"]];
1230
1231	if (NOT $NFT)
1232	bounce("That NFT does not exist");
1233
1234	if (trigger.address == $NFT.soldBy)
1235	bounce("You cannot buy/bid on your own NFTs");
1236
1237	if (trigger.output[[asset="base"]].amount < $NFT.bid * (1 + $MIN_BID_INCREMENT))
1238	bounce("You have to send at least " \|\| $NFT.bid * (1 + $MIN_BID_INCREMENT) \|\| " bytes as you need to increment the current bet by at least 0.01%");
1239	}",
1240	"messages": [
1241	{
1242	"app": "state",
1243	"state": "{
1244	var["FREE_" \|\| trigger.data["NFT"]] \|\|= {bid: trigger.output[[asset="base"]].amount, at: timestamp, by: trigger.address};
1245	var["locked"] += trigger.output[[asset="base"]].amount;
1246	}"
1247	}
1248	]
1249	},
1250	{
1251	"if": "{
1252	trigger.data["method"] == "FREE_CLAIM"
1253	}",
1254	"init": "{
1255	if (NOT trigger.data["NFT"])
1256	bounce("NFT field is mandatory");
1257
1258	$NFT = var["FREE_" \|\| trigger.data["NFT"]];
1259
1260	if (NOT $NFT)
1261	bounce("NFT not found");
1262
1263	if ($NFT.soldAt < timestamp)
1264	bounce("The auction/sale is not over yet");
1265
1266	$isAuction = $NFT.bid ? true : false;
1267	}",
1268	"messages": [
1269	{
1270	"if": "{
1271	$NFT.by != $NFT.soldBy
1272	}",
1273	"app": "payment",
1274	"payload": {
1275	"asset": "base",
1276	"outputs": [
1277	{
1278	"address": "{$NFT.soldBy}",
1279	"amount": "{$NFT.price * (1 - $FREEMARKET_CUT)}"
1280	}
1281	]
1282	}
1283	},
1284	{
1285	"app": "payment",
1286	"payload": {
1287	"asset": "{trigger.data["NFT"]}",
1288	"outputs": [
1289	{
1290	"address": "{$NFT.by}",
1291	"amount": 1
1292	}
1293	]
1294	}
1295	},
1296	{
1297	"app": "state",
1298	"state": "{
1299	var["FREE_" \|\| trigger.data["NFT"]] = false;
1300	var["FREESOLD_" \|\| trigger.data["NFT"]] = $stripToken($NFT);
1301	}"
1302	}
1303	]
1304	}
1305	]
1306	}
1307	}
1308	]